Verbesserter Schildeffekt (TC)

Einheit 101 · Post by **Einheit 101** » Thu, 4. Jul 13, 18:32

Ich seh mir das heute abend noch an. Merci!

daye · Post by **daye** » Thu, 4. Jul 13, 19:22

Wobei mir das '$al.state' Array bzw. die globale Variable al.ShieldID im Schildblasenscript nicht aus dem Kopf geht. Kann ja sein, dass ich jetzt wieder Fehlerteufelchen spiele, aber ich habe in einem Script von mir in meinem Spiel auch einmal das Problem mit einem Schalter gehabt. Das war auch ein mehrstufiges Array. Da ging das bei mir jedenfalls nicht, dass wenn das True an Array[3]-Stelle war, dass ich die globale Var einfach mit Array=True/False abfragen konnte, sondern vorher z. B. var=Array[3] machen musste, dann war 'var' der True/False Zustand des Arrays. Denn auch wenn True/False im Array enthalten war, so konnte ich nicht einfach aus der globalen Abfrage das True erhalten.

Ich sehe hier nur gie globale Abfrage:

$al.State = get global variable: name='al.ShieldID'
if $al.State == [TRUE]

Aber in der globalen al.ShieldID ist doch das True/False an 2 Stelle, oder?

Müsste dann nicht vor der Abfrage:

$AL.STATE.VERSION = 0
$AL.STATE.ENABLED = 1

stehen
und dann

$al.State = get global variable: name='al.ShieldID'

$al.state = $al.state[$AL.STATE.ENABLED]
if $al.State == [TRUE]

O.k., möge mich der bessere verbessern. Ich lerne ja auch gerne dazu

gruß
daye

Einheit 101 · Post by **Einheit 101** » Thu, 4. Jul 13, 19:37

Ja Das Stimmt. Vor Dem Problem Stand Ich heut Mittag Auch. Hatte Aber Keine Zeit.

€DIT::: Ich hab das Problem nun einigermaßen im Griff, versuche aber noch das ganze so hinzubiegen, dass der Status nach dem Laden des Spielstandes bestehen bleibt.

€DIT 2::: Ich habe das Problem nun auf eine etwas andere, jedoch funktionierende Art gemeistert:

Script "a111" (blöder name, ich weiß) erstellt die Blasen etc.

Code: Select all

$state = get global variable: name='shield.state'
if not $state == 0
...
...
...
...
end
return null

Script "plugin.shield.main"

Code: Select all

$AL.STATE.VERSION = 0
$AL.STATE.ENABLED = 1

$al.State = get global variable: name=$al.ShieldID
if not $al.State
  $al.State = array alloc: size=2
  $Version = get script version
  $al.State[$AL.STATE.VERSION] = $Version
  $al.State[$AL.STATE.ENABLED] = [TRUE]
  set global variable: name=$al.ShieldID value=$al.State
end

$al.Retval = null
if $al.Event == 'init' OR $al.Event == 'reinit'
  al engine: set plugin $al.ShieldID description to 'Schalter für Schildeffekte'
  $state = $al.State[$AL.STATE.ENABLED]
  if $state == 0
    START $null->call script 'plugin.shield.off' :
  end
  
else if $al.Event == 'start'
  $al.State[$AL.STATE.ENABLED] = [TRUE]
  START $null->call script 'plugin.shield.on' :
  
else if $al.Event == 'stop'
  $al.State[$AL.STATE.ENABLED] = [FALSE]
  START $null->call script 'plugin.shield.off' :
  
else if $al.Event == 'isenabled'
  $al.Retval = $al.State[$AL.STATE.ENABLED]
  return $al.Retval
end
return null

Scripts "plugin.shield.on" und "plugin.shield.off"

Code: Select all

set global variable: name='shield.state' value=1
write to player logbook 'Schildeffekte ein.'
return null

Code: Select all

set global variable: name='shield.state' value=0
write to player logbook 'Schildeffekte aus.'
return null

----> Wie man sieht, startet das AL Plugin an sich je nach Status einen von zwei separaten Scripts, welche dann eine globale Variable auf 0 oder 1 ändern. Diese Änderung wird vom Schildscript erkannt. Ist nun diese Variable NICHT 0 (also AUS), dann wird der Script normal ausgeführt. Dies war nötig, weil das AL Plugin an sich anscheinend nicht in der Lage war, die Variablen selbst zu setzen (warum auch immer, es wurde stets nur null erkannt), darum habe ich es jetzt so gelöst.

Einen kleinen Haken hat die Geschichte dennoch: Die Änderung wird stets nur bei Sektorwechsel übernommen bzw. wenn ein anderes Schiff den aktuellen Sektor betritt. Dies Gilt auch für das Laden eines Spielstandes: Selbst wenn das Plugin AUS ist, sind die Effekte nach dem Laden eines Spielstandes noch so lange aktiv, bis man den Sektor gewechselt hat oder ein anderes Schiff den Sektor betritt. Da ich dies jedoch persönlich absolut verschmerzen kann, geht die Mod nun offiziell in die große, finale Testphase über: Am Wochenende werden alle Funktionen auf einem anderen Rechner mit separater X³ Vanilla Installation auf Funktion getestet, auftretende Fehler beseitigt und danach

kommt das Release am Sonntag.

Chaber · Post by **Chaber** » Thu, 4. Jul 13, 22:30

spawn doch einfach "weiiiiit außerhalb" irgendein Schiffchen was du direkt wieder zerstörst wenn der Spieler ein, bzw ausschaltet.

ist vermutlich nur ne kleine erweiterung die das ganze dann aber "sauber" aussehen lässt und den Effekt "direkt" wirken lässt

Einheit 101 · Post by **Einheit 101** » Fri, 5. Jul 13, 11:37

Also Das Erstellen Eines Schiffes Löst Den Script Nicht Aus. Alternativ Könnte Ich Evtl Den Script Per Befehl Neu Laden, Aber Müsste Ich Dazu Nicht Die Vorige Instanz stoppen, Damit Das Nicht Doppelt Läuft?

Chaber · Post by **Chaber** » Fri, 5. Jul 13, 15:28

Und wenn du mittels "AI-Schalter" nur ein Skript startets das dann dein eigendliches skript stoppt und neustartet?
praktisch ein Skript vor dem Skript?

Einheit 101 · Post by **Einheit 101** » Fri, 5. Jul 13, 15:42

Ich muss mal sehen ob es ne funktion gibt, die den script stoppt und neu startet. Heute ist dafür aber keine Zeit mehr für mich.

Post by **UniTrader** » Fri, 5. Jul 13, 18:53

zum deaktivieren einfach in die Hauptschleife (oder an diversen stellen im hauptscript, die regelmässig durchlaufen werden) ein

skip if *globale var gesetzt*
| return null

und zum aktivieren einfach den Hauptscript direkt "kickstarten"

Einheit 101 · Post by **Einheit 101** » Sat, 6. Jul 13, 11:35

Das problem ist, dass, während eine While schleife läuft, die globalen Variablen nicht aktualisiert werden, selbst wenn da steht "get global variable...." wird die nur ein mal geholt und nie mehr neu geladen. Wenn ich also die ändere, passiert nix. Außerdem ist im Hauptscript das "THIS" Argument gefordert (Also das schiff, das den sektor betrat), beende ich nun alle instanzen von jedem Schiff im sektor, kann ich das nicht mehr neu starten, weil ja THIS nicht mehr bekannt ist :/
Ich hab jetzt einfach mal mit Testen angefangen.

daye · Post by **daye** » Sun, 14. Jul 13, 00:33

Hallo Einheit 101. Ich nochmal.

Es gibt gute Neuigkeiten zu vermelden, was das Einbinden von M3 / TS / TM etc. betrifft. Habe mir die Woche ein paar kleinere und größere Blasen gebastelt und ein wenig gespielt und auch ein paar Kämpfe mit größeren Ansammlungen gehabt. Keine bis sehr wenig spürbare Performanceeinbrüche.

Dies nur als Info, falls Du dir doch noch überlegst kleinere Schiffe einzubinden. So schlimm, wie man eigentlich befürchten müsste, läuft es dann gar nicht. Also bei mir habe ich alle Schiffe eingebunden, bis auf M4, M5 und eben Sonderdinge wie Sats, Raumfliegen etc. Außer der Tatsache, das mancher Sektor länger zum Laden braucht, kann ich normal wie immer Spielen. Bisher zumindest. Ein Langzeittest steht natürlich noch aus. Will Dich nur etwas ermutigen, weil es sieht wirklich toll aus was Du da gemacht hast und ich persönlich bin begeistert. O.k. bei heißen Gefechten kommt es wegen der Schildeffekte schonmal vor, dass man fast Blind fliegt, weil der Effekt die Sicht schon einschränkt, aber das sehe ich eher als Herausforderung an.

Ein paar Bilder habe ich auch gemacht. Vielleicht interessierts ja auch andere und Sie bekommen Lust auf deine Extraerweiterung zu den Schildeffekten. Dann mal weiterhin gut Mod!

gruß
daye

Das war ein Test bei der Phönix. Mittlerweile ist die Blase vergrößert:

[ external image ]

Feuergefecht in der Ferne.

[ external image ]

TM Klasse

[ external image ]

Abklingender Schild bei der Deimos

[ external image ]

Hilfe, ich seh nix.

[ external image ]

Menelaus rette uns!

[ external image ]

Ich werde angegriffen und schieße zurück!

[ external image ]

Ich mach dich platt!

[ external image ]

Statt Glühwein, gibts Glühxeni, das neue Eisen heißt Xenon!

[ external image ]

In Nebelsektoren leuchten die Schilde förmlich auf!

[ external image ]

Einheit 101 · Post by **Einheit 101** » Sun, 14. Jul 13, 01:27

Geiler Schei**

Dass die weiße Blase zu hell ist, weiss ich. Ich wollte bereits eine Schönere Alternative Basteln. Rot Und grün sind okay. Die Performance wurde Sehr Lange Von Mir Getestet, dein Positives Ergebnis überrascht Mich Nicht

Mein Tutorial Zum Erstellen Neuer Blasen Ist Mittlerweile So Gut Wie Fertig. Ich überlege Mir, Da Noch Einzubauen, Wie Man Neue Texturen Erstellt. Als Beispiel Im Tutorial Habe Ich Die Walhalla Genommen, Wie Gewünscht

Einheit 101 · Post by **Einheit 101** » Sun, 18. Aug 13, 15:43

Hier der aktuelle Code des gesamten Schildsystems. Die Tutorial/Ressource muss ich noch updaten und hochladen, da sie veraltet sind.

Setup

Code: Select all

global secondary signal map: add signal={SIGNAL_CHANGESECTOR} race=null class={Schiff} script='shield.changesector' prio=0 name='shield.changesector'
load text: id=101
$tmp = get number of subtypes of maintype 7
$ship.shield.arr = array alloc: size=$tmp
* 19 Schiffe mit Schild ausgestattet, 2 als Beispiel angegeben
$tmp.ship = {Goner Angelwing 500024}
$tmp.ship = get subtype of ware $tmp.ship
$tmp.array = create new array, arguments=null, 124, null, null, null
* $palete1 = create special: type=124 addto={SECTOR} x=0 y=0 z=0
$ship.shield.arr[$tmp.ship] = $tmp.array
* *
$tmp.ship = {Goner Raptor Träger}
$tmp.ship = get subtype of ware $tmp.ship
$tmp.array = create new array, arguments=null, 128, null, null, null
* $palete2 = create special: type=128 addto={SECTOR} x=0 y=0 z=0
$ship.shield.arr[$tmp.ship] = $tmp.array
* *
$task = [PLAYERSHIP]->get next available task: starting=6000
[PLAYERSHIP]->start task $task with script 'shield.load' and prio 0: arg1=null arg2=null arg3=null arg4=null arg5=null
* end
return null

Erläuterung: Ich hab da mal einiges zur besseren Übersicht weggelassen. Ist ja alles nur CopyPaste.

"shield.changesector" Wird bei Sektorwechsel / Abdocken ausgeführt:

Code: Select all

= wait 1000 ms
$task = [THIS]->get next available task: starting=10900
[THIS]->start task $task with script 'shield.load' and prio 0: arg1=null arg2=null arg3=null arg4=null arg5=null
return null

Erläuterung: Da es zu Fehlern kam, als ich den folgenden Script direkt mit Sektorwechsel starten wollte, habe ich diesen hier zuerst ausgeführt, der 1000ms wartet, bis er den folgenden startet. Es gab so weit ich noch weiß ein Problem, weil das Spiel es zu so einem frühen Zeitpunkt noch nicht gerafft hat, dass ich in einem neuen Sektor bin.

"shield.load" Wird vom vorherigen Script gestartet:

Code: Select all

= wait 250 ms
if [THIS] == [PLAYERSHIP]
  $ship.arr = [SECTOR]->get ship array from sector/ship/station
  $palette1 = get global variable: name='palette'
  $palette1->destruct: show no explosion=[TRUE]
  $palette1 = create special: type=169 addto=[SECTOR] x=0 y=0 z=0
  $palette1->ignore collisions: [TRUE]
  set global variable: name='palette' value=$palette1
  START $null->call script 'shield.palette.schleif' : shield=$palette1
else
  $ship.arr = create new array, arguments=[THIS], null, null, null, null
end
$ship.shield.arr = get global variable: name='plugin.shields.typearray'
$ship.size = size of array $ship.arr
while $ship.size
  dec $ship.size =
  $ship = $ship.arr[$ship.size]
  $ship.type = $ship->get subtype
  $shield.type = $ship.shield.arr[$ship.type]
  if not $shield.type == null
    $task = $ship->get next available task: starting=8000
    $ship->start task $task with script 'a111' and prio 0: arg1=null arg2=null arg3=null arg4=null arg5=null
  end
end
return null

Erläuterung: Der hier lädt die Palette (ein "Puffer" der alle Texturen beinhaltet) bei Sektorwechsel und veranlasst die Palette, dem Spieler zu folgen. Außerdem wird ein Array mit allen Schiffen erstellt und geschaut, ob Schiffe dabei sind, die Blasen haben.

"a111" Der Hauptteil. Er erstellt die Blasen:

Code: Select all

$state = get global variable: name='shield.state'
if not $state == 0
  $shield.type.arr = get global variable: name='plugin.shields.typearray'
  $tmp = [THIS]->get subtype
  $shield.type.arr = $shield.type.arr[$tmp]
  skip if $shield.type.arr != null
    return null
* *
  $ran.max = size of array $shield.type.arr
  dec $ran.max =
  while [THIS]->is in same sector as [PLAYERSHIP]
    $strength = [THIS]->get shield percent
    if $strength >= 3
      $vorher = [THIS]->get current shield strength
      = wait 120 ms
      $nachher = [THIS]->get current shield strength
      if $nachher < $vorher
        $sec = [THIS]->get sector
        $x = [THIS]->get x position
        $y = [THIS]->get y position
        $z = [THIS]->get z position
        $a = [THIS]->get rot alpha
        $b = [THIS]->get rot beta
        $g = [THIS]->get rot gamma
* *
        $ran = random value from zero to $ran.max - 1
        inc $ran =
        $shield.type = $shield.type.arr[$ran]
        $shield = create special: type=$shield.type addto=$sec x=$x y=$y z=$z
        $shield->set rotation: alpha=$a beta=$b gamma=$g
        $shield->ignore collisions: [TRUE]
        $task = [THIS]->get next available task: starting=9000
        [THIS]->start task $task with script 'shield.schleif' and prio 0: arg1=$shield arg2=null arg3=null arg4=null arg5=null
        START $null->call script 'plugin.shield.destroy' : shield=$shield
      end
    end
    = wait 0 ms
  end
end
return null

"shield.palette.schleif" Die Schleife für die Bewegung der Palette:

Code: Select all

while $shield->exists
  = wait 0 ms
  $clas = [PLAYERSHIP]->get object class
  if not $clas == {Astronaut 2064}
    $x = [PLAYERSHIP]->get x position
    $y = [PLAYERSHIP]->get y position
    $z = [PLAYERSHIP]->get z position
    $a = [PLAYERSHIP]->get rot alpha
    $b = [PLAYERSHIP]->get rot beta
    $g = [PLAYERSHIP]->get rot gamma
    $shield->force position: x=$x y=$y z=$z
    $shield->set rotation: alpha=$a beta=$b gamma=$g
  end
end
return null

Erläuterung: Der Raumanzug ist so klein, dass die Palette unangenehm auffällt. Daher wurde er ausgenommen.

"shield.schleif" Die Schleife für die Bewegung der Schilde:

Code: Select all

while $shield->exists
  = wait 0 ms
  $x = [THIS]->get x position
  $y = [THIS]->get y position
  $z = [THIS]->get z position
  $a = [THIS]->get rot alpha
  $b = [THIS]->get rot beta
  $g = [THIS]->get rot gamma
  $shield->force position: x=$x y=$y z=$z
  $shield->set rotation: alpha=$a beta=$b gamma=$g
end
return null

"plugin.shield.destroy" Zerstört die Schilde:

Code: Select all

if $shield->exists
  = wait 850 ms
  $shield->destruct: show no explosion=[TRUE]
end
return null

AL Plugin registrierung:

Code: Select all

al engine: register script='al.shield.main'
return null

AL Plugin abschalten:

Code: Select all

set global variable: name='shield.state' value=0
write to player logbook 'Schildeffekte AUS. Status wird nach Sektorwechsel übernommen oder wenn ein anderes Schiff diesen Sektor betritt.'
return null

AL Plugin anschalten:

Code: Select all

set global variable: name='shield.state' value=1
write to player logbook 'Schildeffekte EIN. Status wird nach Sektorwechsel übernommen oder wenn ein anderes Schiff diesen Sektor betritt.'
return null

daye · Post by **daye** » Sun, 18. Aug 13, 17:21

Auch auf die Gefahr hin, dass ich dich jetzt vielleicht nerve. Tutorial und Ressource sind ja wirklich ein feiner Zug von dir. Doch die Zielgruppe dürfte dann eher der fortgeschrittene Modder oder Leute sein die sich gerne lange in etwas einarbeiten. Glaubst Du also nicht auch, dass ein eigenständiges Schildblasen-Mod-Paket mehr Abnehmer finden würde? Ich denke nicht, dass ich so falsch liege, wenn ich behaupte, dass die meisten doch eher Nutzer von Scripts und Mods sind und weniger selber großartig am Spiel herumbasteln, oder?!

Ich habe mir ja deine Schildblasen aus dem Nexus-Mod rausgezogen. Ein paar eigene dazu gemoddet und ein paar Schild-Scripte von dir modifiziert bzw. neu geschrieben, damit man ein "to go"-Paket hat, was im eigentlichen jeder der Lust hat sofort für TC oder auch angepasst für AP nutzen könnte. Gut es mag nicht perfekt sein, da ich über die Schiffsklasse gehe in den angepassten Scripts und einige Blasen vielleicht nich ganz Ideal für das eine oder andere Schiff sind. Aber im Großen und Ganzen habe ich mich bemüht es relativ ausgeglichen hinzubekommen.

Ich werde davon natürlich nichts veröffentlichen, aber ich würde dir gerne dieses Paket zukommen lassen, wenn Du magst. Dann könntest Du es dir ansehen und wenn es für Dich passt allen Interessierten zur Verfügung stellen?!

Leider ist ja bisher kaum Feedback zu deiner Arbeit von anderen gekommen. Das finde ich immer Schade, wenn engagierte Projekte so diskussionslos bleiben.

Überlege es dir. Ist nur ein Vorschlag, weil ich deine Arbeit wirklich toll finde. Aber wie an anderer Stelle schon gesagt. Dein Baby und deine Entscheidung.

gruß
daye

Einheit 101 · Post by **Einheit 101** » Sun, 18. Aug 13, 18:01

Im Moment herrscht das Problem, dass ein Bug existiert, wenn der Spieler abdockt. Dann bleibt der Script nämlich hängen und ich habe noch keine Ahnung, wie das in den Griff zu bekommen ist. Mit einem Wait habe ich das etwas entschärft, aber nach einem 2. Abdocken ist spätestens schluss. Und da es mir schlicht an Zeit mangeln wird ab der nächsten Zeit (Urlaub vorüber), kann ich dieses To-Go Paket nicht weiter verfolgen und bin schon vorher aus diesem Grund dazu übergegangen, es als Resource zu veröffentlichen. Das Tutorial und die Scripts darin muss ich allerdings nach beseitigung der Fehler nochmal überarbeiten. Wenn du willst, kannst du dein Paket ruhig veröffentlichen. Damit hab ich kein Problem. Es ist besser, wenn das ein anderer macht, allerdings empfehle ich zu warten, bis die finale Version draußen ist.

daye · Post by **daye** » Sun, 18. Aug 13, 18:41

Wie meinst Du das mit dem "hängen bleiben" des Scripts? Funktionieren dann die Schildblasen nach dem Abdocken nicht mehr? Beendet sich das Script? Oder hängt das Spiel = Freeze?!

Also ich kann hier nicht davon berichten, dass das/ein Schild-Script einfriert nach dem Abdocken oder gar das Spiel. Aber wie schon geschrieben, habe ich deine Scripts teilweise neu verfasst bzw. modifiziert. Vielleicht tritt deshalb der "Fehler" nicht auf.

Ich weiß allerdings, dass ich mit deiner Version der Scripte das Problem hatte, dass wenn ich in den Raumanzug stieg und ein neues Schiff betrat, dann funktionierte das Schildscript nicht mehr. Aber das habe ich durch eine zusätzliche lokale Var auf dem Spielerschiff gelöst die einfach auf 1 steht, wenn der Spieler im Schiff ist. Wenn der Spieler ein neues Schiff betritt und die Var nicht 1 ist, dann reloaded er das Schildplugin einfach und die Schildblasen funktionieren wieder.

Schade zu hören, dass es deine Zeit nicht erlaubt ein eigenständiges Schild-Paket zu veröffentlichen. Ich bin dir natürlich dankbar für die Genehmigung so ein "to go"-Paket auf Grundlage deiner Arbeit veröffentlichen zu dürfen und würde natürlich selbstredend darauf Hinweisen das deine Arbeit die Basis dieses Paketes ist/wäre.

Aber das muss ich mir durch den Kopf gehen lassen.

gruß
daye

Einheit 101 · Post by **Einheit 101** » Sun, 18. Aug 13, 18:58

Wenn dein modifizierter Script nicht stehen bleibt, dann wäre es in der Tat vielleicht nett, wenn du mir den zukommen lassen könntest. Das mit dem Raumanzug ist mir unbekannt und wird getestet. Mein Problem besteht darin, dass der Script stehen bleibt, wenn ich mit meinem Jäger von meinem Träger starte, was auf das SIGNAL_CHANGESECTOR wohl zurückzuführen ist.

daye · Post by **daye** » Sun, 18. Aug 13, 19:09

Nun ja, ich kann dir nur das Komplettpaket als Link per PM zukommen lassen. Ein einzelnes Script wird dir nix nützen, weil ich fast alles an den Scripts verändert/angepasst habe.

Somit ist meine Version nicht mehr Kompatibel zu deiner und würde nur zu Chaos führen.

gruß
daye

Einheit 101 · Post by **Einheit 101** » Sun, 18. Aug 13, 19:17

Okay danke. Dann werde ich das mal mit bekannten Fehlern testen und wieder für mein System umbauen, damit es funktioniert.

daye · Post by **daye** » Sun, 18. Aug 13, 19:29

Hast die PM schon erhalten? Weil ich muss plötzlich den Cache löschen beim Firefox, sonst kann ich keine Antwort schreiben. Irgendwie spinnt der mal wieder.

Weil wenns net angekommen ist, dann mach ichs mit dem IE.

gruß
daye

Einheit 101 · Post by **Einheit 101** » Sun, 18. Aug 13, 19:38

Irgendwas ist angekommen^^ ich schau mal nach.

egosoft.com

egosoft.com

Verbesserter Schildeffekt (TC)