[MOD] [AP] LxXRM 3.1 - Lucike XRM Resurrection Modding Package [updated 06.10.2019]

[Corsair1]

Hey all,

Wondering how to actually salvage anything larger than an M3.

The instruction say to use System Override Software, which is an illegal good.....So I cant use it as I'll have to dump it every time I get scanned?

I set it to use the other options, salvage command and special command software. But if I click claim all wrecks in sector, it just says I dont have System Override Software installed.

Anyone who knows, can I get a walkthrough on this.

Cheers

[Hariwulf]

Pictures not working, it's a little hard without them, but I managed and...wow! O.O

o7

[Hariwulf]

I have a bug where guns appear and disappear (from inventory too) as I fly around.
No further modification than LxXrm

[unknown1]

Hey all,

Wondering how to actually salvage anything larger than an M3.

The instruction say to use System Override Software, which is an illegal good.....So I cant use it as I'll have to dump it every time I get scanned?

I set it to use the other options, salvage command and special command software. But if I click claim all wrecks in sector, it just says I dont have System Override Software installed.

Anyone who knows, can I get a walkthrough on this.

Cheers

Visit the pirate bases , i know that sometimes they sell the ''software signature scrambler''. I don't remember if there is a specific pirate base or it's random. It's been 15 years since i last played. That piece of tech will hide the System Override Software from scans, you will no longer have to drop it.

[ntweedie2007]

Is there Satellite Monitoring in this for keeping an eye on NPC bailing outside of your own sector (from NPC v. NPC fights)? LU has this. It's kinda vital when there is NPC bailing otherwise you'd never know when it happened outside of your own fights.

Would LU's Satellite Monitoring mod work with XRM?

[ntweedie2007]

How To Setup after Start

[...]

- enable the repair lasers stations
You can buy and setup some M3 and M6 with that, repairing big ships in a very short time. You will need that later.
[...]

This isn't an option in the Artificial life settings - "- enable the repair lasers stations
You can buy and setup some M3 and M6 with that, repairing big ships in a very short time. You will need that later."

[ntweedie2007]

I don't know what half the mods in this do or what they are called. Can I get help with the following please -

- What do you do with the wrecks of destroyed ships? I assume they are there to be scavenged, but how? With what software? What command?

- What are the $ signs beside some ships? How do I interact with them or use this feature?

Adding all the mods is great, but I've no clue what 90% of them do

[X2-Illuminatus]

Would LU's Satellite Monitoring mod work with XRM?

No, it wouldn't.

I don't know what half the mods in this do or what they are called.

...

Adding all the mods is great, but I've no clue what 90% of them do

Which begs the question whether it was such a good idea to install this mod in the first place. Why don't you start with a clean XRM installation, make yourself familiar with all the features XRM already offers to begin with, and then look for specific scripts and mods to change the game experience to your likings?

[ntweedie2007]

I played as Poisoned Paranid start - how do I access Terran sectors? I get a warning if I try to enter them, rep is 1. I need to get the SCH's to make complexes.

Is there a trigger or a point I need to get to?

[Fureimuu]

In order to play this you need X3 resurrection, which needs XRM compatibility files, which you can't get because the author's site is down. Not ideal.

[qibisa]

.bat installer doesn't recognize any files in _DOWNLOADS folder.

I've done everything as per the instruction and the only snag so far is that installer just doesn't see the provided archives.
Win10 x64, tried disabling antivirus, running as admin, repacking .zip into .rar, pretty much everything I could think off.

Contents of my _DOWNLOADS folder: https://i.imgur.com/ivKM5OF.png
Yet installer doesn't see the files there: https://i.imgur.com/ufjX5ij.png
Going through with the installation regardless just gives errors on files not found: https://i.imgur.com/CkPKuRM.png
And there is no effect in game after the failed installation, it stays vanilla. Using freshly installed steam version of AP.
Any ideas?

EDIT: Come to think about it, it says "0 files were copied" for everything there, so the installer doesn't even see its own files. What gives?
EDIT2: Celestia's swollen tits, this is bothersome, spent two hours on this.
Okay, so turns out the SETUP.bat was running inside system32 instead of LxXRM folder. Fixed this by
commenting away lines 7 and 8 inside that were *supposed* to prevent just this error.
Then had to repack three parts of XRM so that necessary files were just inside the archive, not in the folder inside the archive.
Then had to install it onto steam version, because no-steam version is bollocks and redirects to vanilla steam install directory. (was too lazy to create fake exe pointing to separate install).
At least it all looks working finally. Argon prime shipyard has new station and everything else has eye candy. I'll proceed from here, hope my wasted time in installing this will help someone else later with these problems.

[atsjewell]

Does anybody know where one can find "accurate" data for the ships, weapons, missiles, etc. in this mod.
There are so many discrepancies between the online XRM 1.30d databases versus the in-game encyclodia. I even tried opening up the cat files with X3 Editor 2 and it's only adding to the confusion.

One Example: Banshee Missile.
XRM AP 1.30d Missile Table: Size is 8 L
09.cat/types/TMissile.pck: Size is 8 L
In-game encyclopedia: Size is 6 L
Examining a ship's Freight in-game seems to confirm the 6 L value.

This would indicate the XRM database is wrong.. but then how is the CAT file wrong? You would think THAT would be the source of truth if anything.

Also, does anyone know where in the game files the "meta" type information can be found.. (missile behaviour, station docking, etc.) None of this seems apparent from the TMissile.pck or TDock.pck files.
Given that the in-game encyclopedia is next to useless, and the online XRM databases appear to be innaccurate, I'm determined to compile the data myself even if I have to scour all the game files.

[unknown1]

Does this have all the features of LU? ( litcube's universe) like mobile mining ?

[heimdallxx]

Hello, Resurrection mod doesn't have patch or other files right now just XRM 3.3 version available for download. And the installer doesn't accept it. Do you know any ways to fix it ?

Update:

I figure it out. Go https://drive.google.com/drive/folders/ ... dsT2yjbALG and inside folder name "original resurrection. there is old version of resurrection 3.0 and , 3.3 patch and XRM Comp. patch. after you download all three you need to open every archive and go inside the folders and extract files to somewhere and archive them again as .rar file. while you doing that change the names of new archives as mentioned in installation at first page. after that in .bat installer type "r" and everything should be ok.

[Davith]

Hello, Resurrection mod doesn't have patch or other files right now just XRM 3.3 version available for download. And the installer doesn't accept it. Do you know any ways to fix it ?

Hi, I went ahead and edited the script to use the single Resurrection-XRM rar. All you should need to do is replace the `setup.bat` with the code below (in the spoiler), and rename the downloaded Resurrection rar (`X3 - Resurrection - v3.3 - XRM`) to `X3-ResurrectionXRM.rar`. (The name change is because the bat script didn't seem to like the name containing spaces and/or dashes . The other changes in the script were just me trying to understand a bat file)

The install seems to be going fine for me so far, but I haven't done any in-depth check to see if the newer resurrection has any issues with the rest of the pack.

Spoiler

Show

Code: Select all

@echo off
setlocal enabledelayedexpansion

:: Sanity execution direction setting
:: Needed when the bat file is executed as admin because its then executed in system32 
:: check: http://stackoverflow.com/questions/672693/windows-batch-file-starting-directory-when-run-as-admin/672721
FOR /F "delims=" %%I IN ("%0") DO SET dr=%%~dpI
cd /D %dr%

set _vars=!dr!/_settings.txt
set _x3ap_exe=X3AP.exe
set _x3_backup=_tmp_LXRM_BACKUP

set _f_x3ap=_DOWNLOADS\!_x3ap_exe!
set _f_x3_resurrection="_DOWNLOADS\X3-ResurrectionXRM.rar"
set _f_xrm_part_1=_DOWNLOADS\XRM1.30_PART_1.zip
set _f_xrm_part_2=_DOWNLOADS\XRM1.30d_PART_2.zip
set _f_xrm_part_3=_DOWNLOADS\XRM1.29_PART_3.zip

set pkg_130=130 - FP-08_09-XRM
set pkg_170=170 - FP-13_15-Resurrection

::-------------------------------------------------------------------
:: User options
set _opt_x3path=.
:: tc plots in ap
set _opt_enable_tcap=1
set _opt_disable_argon_terran_war=0
set _opt_include_LoCo=1
set _opt_xrm_hull_strength=2
set _opt_enable_CPP_performance=1
set _opt_patch_w_x3_customizer=1
set _opt_enable_awesomefied_weapons=1
set _opt_enable_awesomefied_bullets=1
set _opt_enable_scripts=1
set _opt_install_larger_font=1

::-------------------------------------------------------------------
set _c_white=[90m
set _c_red=[91m
set _c_green=[92m
set _c_reset=[0m

:: try to read in old settings
for /f "usebackq tokens=1* delims==" %%A in ("%_vars%") do set %%A=%%B


set _xtra=0

::-------------------------------------------------------------------------------------------------
:menu
set _x3_missing=0
set _x3_path_good=0
set _x3_TWareT_good=0
cls

echo LxXRM v3.0 Setup
echo.
echo Files
echo -----
:: First we must ensure the extra mods have been downloaded
call :CheckExtraDownloadExists !_f_x3ap!
call :CheckExtraDownloadExists !_f_x3_resurrection!
call :CheckExtraDownloadExists !_f_xrm_part_1!
call :CheckExtraDownloadExists !_f_xrm_part_2!
call :CheckExtraDownloadExists !_f_xrm_part_3!
echo.


:: Path to the x3 addon folder; this is where to install mods for x3ap.
set x3path_addon=!_opt_x3path!/addon

if !_xtra!==1 goto xtra


::-------------------------------------------------------------------------------------------------
:: Configuration Block

echo Configure
echo ---------

:: TCAP
if !_opt_enable_tcap!==0 (set t_opt_enable_tcap=!_c_white!no!_c_reset!) else (set t_opt_enable_tcap=!_c_green!yes!_c_reset!)
echo 1] Install and enable TCAP missions: !t_opt_enable_tcap!

:: XRM Argon/Terran War
if !_opt_disable_argon_terran_war!==0 (set t_opt_disable_argon_terran_war=!_c_white!no!_c_reset!) else (set t_opt_disable_argon_terran_war=!_c_green!yes!_c_reset!)
if !_opt_enable_tcap!==1 (set t_opt_disable_argon_terran_war=!_c_white!*disabled by TCAP*!_c_reset!)
echo 2] install XRM "No Argon/Terran War Pack" script?: !t_opt_disable_argon_terran_war!

:: Lost Colonies
if !_opt_include_LoCo!==0 (set t_opt_include_LoCo=!_c_white!no!_c_reset!) else (set t_opt_include_LoCo=!_c_green!yes!_c_reset!)
echo 3] Install Lost Colony systems? [recommended]: !t_opt_include_LoCo! 

:: XRM Hull Strength
if !_opt_xrm_hull_strength!==0 (set t_opt_xrm_hull_strength=!_c_white!no!_c_reset!)
if !_opt_xrm_hull_strength!==1 (set t_opt_xrm_hull_strength=!_c_green!low!_c_reset!)
if !_opt_xrm_hull_strength!==2 (set t_opt_xrm_hull_strength=!_c_green!medium!_c_reset! [recommended])
if !_opt_xrm_hull_strength!==3 (set t_opt_xrm_hull_strength=!_c_green!high!_c_reset!)
echo 4] XRM hull strength? None, Low, Medium (recommended) or High: !t_opt_xrm_hull_strength!

:: CPP Performance
if !_opt_enable_CPP_performance!==0 (set t_opt_enable_CPP_performance=!_c_white!no!_c_reset!) else (set t_opt_enable_CPP_performance=!_c_green!yes!_c_reset!)
echo 5] Use CPP performance weapon settings? (STRONGLY recommended for performance): !t_opt_enable_CPP_performance!

:: X3 Customizer
if !_opt_patch_w_x3_customizer!==0 (set t_opt_patch_w_x3_customizer=!_c_white!no!_c_reset!) else (set t_opt_patch_w_x3_customizer=!_c_green!yes!_c_reset!)
echo 6] Patch with the included X3 Customizer files? (STRONGLY recommended): !t_opt_patch_w_x3_customizer!

:: Awesomefied Weapons
if !_opt_enable_awesomefied_weapons!==0 (set t_opt_enable_awesomefied_weapons=!_c_white!no!_c_reset!) else (set t_opt_enable_awesomefied_weapons=!_c_green!yes!_c_reset!)
echo 7] Use Awesomefied weapon effects? (STRONGLY recommended for performance): !t_opt_enable_awesomefied_weapons!

:: Awesomefied Bullets
if !_opt_enable_awesomefied_bullets!==0 (set t_opt_enable_awesomefied_bullets=!_c_white!no!_c_reset!) else (set t_opt_enable_awesomefied_bullets=!_c_green!yes!_c_reset!)
if !_opt_enable_awesomefied_weapons!==0 (set t_opt_enable_awesomefied_bullets=!_c_white!*needs awesomefied weapon effects*!_c_reset!)
echo 8] Use Awesomefied bullets too? (additional performance boost): !t_opt_enable_awesomefied_bullets!

:: Use bundled Scripts
if !_opt_enable_scripts!==0 (set t_opt_enable_scripts=!_c_white!no!_c_reset!) else (set t_opt_enable_scripts=!_c_green!yes!_c_reset!)
echo 9] Add mods (scripts + libs) (DO NOT DISABLE): !t_opt_enable_scripts!

echo O] Options
echo.

::-------------------------------------------------------------------------------------------------

goto cmds
:xtra

echo Options
echo -------
if !_opt_install_larger_font!==0 (set t_opt_install_larger_font=!_c_white!no!_c_reset!) else (set t_opt_install_larger_font=!_c_green!yes!_c_reset!)
echo A] Install a larger font? (recommended for higher resolutions): !t_opt_install_larger_font!

echo O] Back to Configure
echo.

:cmds
set _x3_path_good=0
set _x3_TWareT_good=0
IF EXIST "!_opt_x3path!/!_x3ap_exe!" (
    set _x3_path_good=1
    set _x3_TWareT_good=1
    IF Not EXIST "!x3path_addon!/scripts/setup.cycrow.waremanager.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/scripts/setup.cycrow.pmanager.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/scripts/init.community.config.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/types/TWareT.pck" (set _x3_TWareT_good=0)

    echo P] Path to Game: !_c_green!!_opt_x3path!!_c_reset!!_c_white!/!_x3ap_exe!!_c_reset! !_c_green!*FOUND*!_c_reset!
    if !_x3_path_good!==0 (
        set _x3_missing=1
        echo !_c_red!PluginManager files not found : Run it before install.!_c_reset!
    )
    if !_x3_path_good!==1 if !_x3_TWareT_good!==0 (
        set _x3_missing=1
        echo !_c_red!PluginManager *MUST* be CLOSED when playing or running SETUP.bat!_c_reset!
    )
) ELSE (
    set _x3_missing=1
    if "!_opt_x3path!"=="." (
        echo P] Path to Game: !_c_red!*SET PATH TO DIR*!_c_reset!
    ) ELSE (
        echo P] Path to Game: !_c_red!!_opt_x3path!!_c_reset! / can't find !_x3ap_exe! !_c_red!*INVALID*!_c_reset!
    )
)

if !_x3_missing!==0 (echo I] Install) else (echo I] !_c_white!Install!_c_reset! !_c_red!*NOT READY*!_c_reset!)
echo R] Refresh, D] Deinstall, Q] Quit
echo.

choice /c 123456789pridqo /M "Select: "

if !errorlevel!==1 (
    if !_opt_enable_tcap!==0 (set _opt_enable_tcap=1) else (set _opt_enable_tcap=0)
    goto menu
)

if !errorlevel!==2 (
    if !_opt_disable_argon_terran_war!==0 (set _opt_disable_argon_terran_war=1) else (set _opt_disable_argon_terran_war=0)
    goto menu
)
if !errorlevel!==3 (
    if !_opt_include_LoCo!==0 (set _opt_include_LoCo=1) else (set _opt_include_LoCo=0)
    goto menu
)

if !errorlevel!==4 (
    if !_opt_xrm_hull_strength!==3 (set _opt_xrm_hull_strength=0&goto menu)
    if !_opt_xrm_hull_strength!==2 (set _opt_xrm_hull_strength=3&goto menu)
    if !_opt_xrm_hull_strength!==0 (set _opt_xrm_hull_strength=1&goto menu)
    if !_opt_xrm_hull_strength!==1 (set _opt_xrm_hull_strength=2&goto menu)
    goto menu
)
if !errorlevel!==5 (
    if !_opt_enable_CPP_performance!==0 (set _opt_enable_CPP_performance=1) else (set _opt_enable_CPP_performance=0)
    goto menu
)
if !errorlevel!==6 (
    if !_opt_patch_w_x3_customizer!==0 (set _opt_patch_w_x3_customizer=1) else (set _opt_patch_w_x3_customizer=0)
    goto menu
)
if !errorlevel!==7 (
    if !_opt_enable_awesomefied_weapons!==0 (set _opt_enable_awesomefied_weapons=1) else (set _opt_enable_awesomefied_weapons=0)
    goto menu
)
if !errorlevel!==8 (
    if !_opt_enable_awesomefied_bullets!==0 (set _opt_enable_awesomefied_bullets=1) else (set _opt_enable_awesomefied_bullets=0)
    goto menu
)
if !errorlevel!==9 (
    if !_opt_enable_scripts!==0 (set _opt_enable_scripts=1) else (set _opt_enable_scripts=0)
    goto menu
)
if !errorlevel!==10 (
    echo.
    set /p _opt_x3path=[96mEnter X3AP Path: !_c_reset!
    echo '!_opt_x3path!'

    if "!_opt_x3path!"=="" (!_opt_x3path!=.)
    goto menu
)

if !errorlevel!==11 (
    goto menu
)

if !errorlevel!==12 (
    if !_x3_missing!==1 (echo.&echo Fix the missing parts first...&pause&goto menu)    
    goto install_start
)

if !errorlevel!==13 (
    goto un_files
)


if !errorlevel!==14 (
    >!_vars! echo _opt_x3path=!_opt_x3path!
    >>!_vars! echo _opt_enable_tcap=!_opt_enable_tcap!
    >>!_vars! echo _opt_disable_argon_terran_war=!_opt_disable_argon_terran_war!
    >>!_vars! echo _opt_include_LoCo=!_opt_include_LoCo!
    >>!_vars! echo _opt_xrm_hull_strength=!_opt_xrm_hull_strength!
    >>!_vars! echo _opt_enable_CPP_performance=!_opt_enable_CPP_performance!
    >>!_vars! echo _opt_patch_w_x3_customizer=!_opt_patch_w_x3_customizer!
    >>!_vars! echo _opt_enable_awesomefied_weapons=!_opt_enable_awesomefied_weapons!
    >>!_vars! echo _opt_enable_awesomefied_bullets=!_opt_enable_awesomefied_bullets!
    >>!_vars! echo _opt_enable_scripts=!_opt_enable_scripts!
    goto :EOF
)

if !errorlevel!==15 (
    if !_xtra!==0 (set _xtra=1) else (set _xtra=0)
    goto menu
)

if !errorlevel!==16 (
    if !_opt_install_larger_font!==0 (set _opt_install_larger_font=1) else (set _opt_install_larger_font=0)
    goto menu
)

goto menu

::-------------------------------------------------------------------------------------------------

:: DELETE files
:un_files

echo.
:: only when we have a valid path
if !_x3_path_good!==0 (
    echo "No X3AP path set ..."
    GOTO un_files_in
)
    
:: Already a backup directory? Then something is wrong
IF Not EXIST "!_opt_x3path!/!_x3_backup!" (
    echo "SKIP cleanup of !_opt_x3path! :: !_x3_backup! did not exists."
    GOTO un_files_in
)

set unfilesx=N
echo.

::-------------------------------------------------------------------------------------------------


:un_filesx_l
set /p "unfilesx=Deinstall mods and restore !_opt_x3path! files [y|n]: "
   if /i "!unfilesx:~,1!" EQU "Y" (goto un_filesx_do)
   if /i "!unfilesx:~,1!" EQU "N" (goto un_files_in)
goto un_filesx_l

::-------------------------------------------------------------------------------------------------


:un_filesx_do

:: remove all installed directories
rd /s /q "!_opt_x3path!\objects" 2>NUL
rd /s /q "!_opt_x3path!\dds" 2>NUL
rd /s /q "!_opt_x3path!\f" 2>NUL
rd /s /q "!_opt_x3path!\L" 2>NUL

Rem remove the addon / AP directories we had backuped
rd /s /q "!_opt_x3path!\addon\t" 2>NUL
rd /s /q "!_opt_x3path!\addon\scripts" 2>NUL
rd /s /q "!_opt_x3path!\addon\types" 2>NUL
rd /s /q "!_opt_x3path!\addon\mov" 2>NUL
rd /s /q "!_opt_x3path!\addon\loadscr" 2>NUL
rd /s /q "!_opt_x3path!\addon\PluginManager" 2>NUL
rd /s /q "!_opt_x3path!\addon\output" 2>NUL

rd /s /q "!_opt_x3path!\addon\Director" 2>NUL
rd /s /q "!_opt_x3path!\addon\Maps" 2>NUL
rd /s /q "!_opt_x3path!\addon\scripts.delete" 2>NUL
rd /s /q "!_opt_x3path!\addon\x3_customizer_logs" 2>NUL

del /Q "!_opt_x3path!\addon\05.*" 2>NUL
del /Q "!_opt_x3path!\addon\06.*" 2>NUL
del /Q "!_opt_x3path!\addon\07.*" 2>NUL
del /Q "!_opt_x3path!\addon\08.*" 2>NUL
del /Q "!_opt_x3path!\addon\09.*" 2>NUL
del /Q "!_opt_x3path!\addon\10.*" 2>NUL
del /Q "!_opt_x3path!\addon\11.*" 2>NUL
del /Q "!_opt_x3path!\addon\12.*" 2>NUL
del /Q "!_opt_x3path!\addon\13.*" 2>NUL
del /Q "!_opt_x3path!\addon\14.*" 2>NUL
del /Q "!_opt_x3path!\addon\15.*" 2>NUL
del /Q "!_opt_x3path!\addon\16.*" 2>NUL
del /Q "!_opt_x3path!\addon\17.*" 2>NUL
del /Q "!_opt_x3path!\addon\18.*" 2>NUL
del /Q "!_opt_x3path!\addon\19.*" 2>NUL
del /Q "!_opt_x3path!\addon\20.*" 2>NUL
del /Q "!_opt_x3path!\addon\21.*" 2>NUL
del /Q "!_opt_x3path!\addon\22.*" 2>NUL
del /Q "!_opt_x3path!\addon\23.*" 2>NUL
del /Q "!_opt_x3path!\addon\24.*" 2>NUL
del /Q "!_opt_x3path!\addon\25.*" 2>NUL

xcopy "!_opt_x3path!\!_x3_backup!\addon\t" "!_opt_x3path!\addon\t\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\scripts" "!_opt_x3path!\addon\scripts\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\types" "!_opt_x3path!\addon\types\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\mov" "!_opt_x3path!\addon\mov\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\loadscr" "!_opt_x3path!\addon\loadscr\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\PluginManager" "!_opt_x3path!\addon\PluginManager\" /s /e /y /q

::-------------------------------------------------------------------------------------------------
:un_files_in
:: check we want clean up the LxXRM install too
set unfiles=N
:un_files_l
set /p "unfiles=Clean installed _DOWNLOAD packs too? [y|n]: "
   if /i "!unfiles:~,1!" EQU "Y" (goto un_files_do)
   if /i "!unfiles:~,1!" EQU "N" (goto un_files_no)
   echo Please type Y for Yes or N for No
   goto un_files_l

:un_files_do
set pkg=!pkg_130!
rd /s /q "!dr!!pkg!\_tmp" 2>NUL
rd /s /q "!dr!!pkg!\X3AP_COPYME" 2>NUL
set pkg=!pkg_170!
rd /s /q "!dr!!pkg!\_tmp" 2>NUL
rd /s /q "!dr!!pkg!\X3AP_COPYME" 2>NUL

::-------------------------------------------------------------------------------------------------
:un_files_no
goto menu

::-------------------------------------------------------------------------------------------------
:install_start
set start_y=N
echo.
:start_y_
set /p "start_y=Start to install? [y|n]: "
   if /i "!start_y:~,1!" EQU "Y" (goto unpack_xrm)
   if /i "!start_y:~,1!" EQU "N" (goto menu)
   echo Please type Y for Yes or N for No
   goto start_y_

::-------------------------------------------------------------------------------------------------
:: Unpack XRM
:unpack_xrm
set pkg=!pkg_130!
IF EXIST "!dr!!pkg!\X3AP_COPYME" (goto unpack_resurrection)

echo "*** Unpack: XRM... ***"
IF EXIST "!dr!!pkg!\_tmp" ( rd /s /q "!dr!!pkg!\_tmp" )
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_1!" -o"!dr!!pkg!\_tmp"
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_2!" -o"!dr!!pkg!\_tmp"
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_3!" -o"!dr!!pkg!\_tmp"

xcopy "!dr!!pkg!\_tmp\scripts_AP" "!dr!!pkg!\X3AP_COPYME\addon\scripts\" /s /e /y
xcopy "!dr!!pkg!\_tmp\t" "!dr!!pkg!\X3AP_COPYME\addon\t\" /s /e /y
xcopy "!dr!!pkg!\_tmp\director" "!dr!!pkg!\X3AP_COPYME\addon\director\" /s /e /y
xcopy "!dr!!pkg!\_tmp\loadscr" "!dr!!pkg!\X3AP_COPYME\addon\loadscr\" /s /e /y
xcopy "!dr!!pkg!\_tmp\mov" "!dr!!pkg!\X3AP_COPYME\addon\mov\" /s /e /y
xcopy "!dr!!pkg!\_tmp\soundtrack" "!dr!!pkg!\X3AP_COPYME\soundtrack\" /s /e /y

copy "!dr!!pkg!\_tmp\XRM1.30_PART_1.cat" "!dr!!pkg!\X3AP_COPYME\addon\08.cat"
copy "!dr!!pkg!\_tmp\XRM1.30_PART_1.dat" "!dr!!pkg!\X3AP_COPYME\addon\08.dat"

copy "!dr!!pkg!\_tmp\XRM1.30d_PART_2.cat" "!dr!!pkg!\X3AP_COPYME\addon\09.cat"
copy "!dr!!pkg!\_tmp\XRM1.30d_PART_2.dat" "!dr!!pkg!\X3AP_COPYME\addon\09.dat"

::-------------------------------------------------------------------------------------------------
:: Unpack Resurrection mod

:unpack_resurrection
set pkg=!pkg_170!
IF EXIST "!dr!!pkg!\X3AP_COPYME" (goto backup)

echo "*** Unpack: Resurrection... ***"
IF EXIST "!dr!!pkg!\_tmp" ( rd /s /q "!dr!!pkg!\_tmp" )
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_x3_resurrection!" -o"!dr!!pkg!\_tmp"

md "!dr!!pkg!\X3AP_COPYME"
md "!dr!!pkg!\X3AP_COPYME/addon"

ren "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3 - Resurrection - v3.3 - XRM.cat" X3-RESURRECTION.cat
ren "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3 - Resurrection - v3.3 - XRM.dat" X3-RESURRECTION.dat

copy "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3-RESURRECTION.cat" "!dr!!pkg!\X3AP_COPYME\addon\13.cat"
copy "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3-RESURRECTION.dat" "!dr!!pkg!\X3AP_COPYME\addon\13.dat"



::-------------------------------------------------------------------------------------------------
:: Create Backup Directory
:backup
IF EXIST "!_opt_x3path!/!_x3_backup!" ( goto install_mods)

echo "*** create  !_opt_x3path!\!_x3_backup! for backup files... ***"
xcopy "!_opt_x3path!\addon\t" "!_opt_x3path!\!_x3_backup!\addon\t\" /s /e /y /q
xcopy "!_opt_x3path!\addon\scripts" "!_opt_x3path!\!_x3_backup!\addon\scripts\" /s /e /y /q
xcopy "!_opt_x3path!\addon\types" "!_opt_x3path!\!_x3_backup!\addon\types\" /s /e /y /q
xcopy "!_opt_x3path!\addon\mov" "!_opt_x3path!\!_x3_backup!\addon\mov\" /s /e /y /q
xcopy "!_opt_x3path!\addon\loadscr" "!_opt_x3path!\!_x3_backup!\addon\loadscr\" /s /e /y /q
xcopy "!_opt_x3path!\addon\PluginManager" "!_opt_x3path!\!_x3_backup!\addon\PluginManager\" /s /e /y /q
copy "!_opt_x3path!\!_x3ap_exe!" "!_opt_x3path!\!_x3_backup!\!_x3ap_exe!"


::-------------------------------------------------------------------------------------------------
:: Install Mods
:install_mods

echo Prepare Base files....
copy "!dr!\!_f_x3ap!" "!_opt_x3path!\!_x3ap_exe!"
:: XRM comes with a 00044.xml in the fake mod
:: to enable it, the 00044.xxx in the /mov must be removed 
del /Q "!x3path_addon!\mov\00044.xml" 2>NUL
del /Q "!x3path_addon!\mov\00044.pck" 2>NUL
:: We install the latest, fixed MK3 Trader scripts
:: remove all previous files to avoid problems
del /Q "!x3path_addon!\scripts\plugin.autotrade*.pck" 2>NUL
del /Q "!x3path_addon!\scripts\plugin.autotrade*.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.signal.killed.trader.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.signal.attacked.trader.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.sh.attack.trader.flee.xml" 2>NUL
del /Q "!x3path_addon!\scripts\!ship.cmd.jump.std.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.get.jumpable.gates.xml" 2>NUL
del /Q "!x3path_addon!\t\1500-L*.xml" 2>NUL

set X3AP_PATH=!_opt_x3path!

echo Installing :: BASE [hud, etc]
xcopy "!dr!000 - BASE\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
if !_opt_install_larger_font!==1 (
    echo Installing :: larger Font
    xcopy "!dr!000 - BASE\LargerFont" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: MK3 reloaded
xcopy "!dr!010 - MK3-Reloaded\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Mars [scripts and t only]
xcopy "!dr!050 - Mars\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Complex Cleaner AP
xcopy "!dr!100 - FP-05-Complex Cleaner\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Lucike [full + modification mod]
xcopy "!dr!110 - FP-06-Lucike\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!110 - FP-06-Lucike\X3TC_AP_Prospector_3_3_07_Signal_Targeted_V1.5" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!110 - FP-06-Lucike\X3TC_AP_Com_Agent_3_4_09_Signal_Targeted_V1.2" "!X3AP_PATH!" /s /e /y /q

echo Installing :: eEQ Docks AP
xcopy "!dr!120 - FP-07-eEQDocks_AP\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: XRM 1.30d
xcopy "!dr!130 - FP-08_09-XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!130 - FP-08_09-XRM\X3AP_mars" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_tcap!==0 if !_opt_disable_argon_terran_war!==1 (
    echo Installing :: XRM "no war scripts"
    xcopy "!dr!130 - FP-08_09-XRM\X3AP_NoWar" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Saturn Complex Hub XRM [AP]
xcopy "!dr!140 - FP-10-SaturnComplexHub\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Advanced Complex Hub [AP]
xcopy "!dr!150 - FP-11-AdvancedComplexHub\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: No Ring Gates
xcopy "!dr!160 - FP-12-NoRingGates\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Resurrection
xcopy "!dr!170 - FP-13_15-Resurrection\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: FM 14 - TWareT
xcopy "!dr!180 - FP-16 - TWareT\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_tcap!==1 (
    echo Installing :: TCAP
    xcopy "!dr!200 - FP-17-TCAP [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_include_LoCo!==1 (
    echo Installing :: Lost Colony XRM
    xcopy "!dr!210 - Lost Colony XRM [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    echo Installing :: TCAP for Lost Colony files
    xcopy "!dr!215 - TCAP_Lost Colony [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Patching: Lucike + XRM [ types / t ]
xcopy "!dr!250 - Lucike+XRM merged\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Revelation XRM
xcopy "!dr!260 - Revelation XRM-AP\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!260 - Revelation XRM-AP\Fixes" "!X3AP_PATH!" /s /e /y /q

echo Installing :: ADS + Pirate Guild + Yaki Guild merged
xcopy "!dr!270 - ADS + PirateGuild + Yaki\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Phanon XRM
xcopy "!dr!280 - Phanon XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Improved Khaak
xcopy "!dr!290 - Improved Khaak\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_awesomefied_weapons!==1 (
    echo Installing :: Awesomefied Weapons
    xcopy "!dr!300 - Awesomefied Weapons\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    echo Installing :: Awesomefied Weapons (+Bullets)
    xcopy "!dr!300 - Awesomefied Weapons\bullets" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Bounce
xcopy "!dr!310 - Bounce\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_xrm_hull_strength!==1 (
    echo Installing ::XRM Hull: low [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\low" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_xrm_hull_strength!==2 (
    echo Installing :: XRM Hull: medium [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\medium" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_xrm_hull_strength!==3 (
    echo Installing :: XRM Hull: high [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\high" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 (
    echo Installing :: Patching: TCAP + Lucike + XRM
    xcopy "!dr!350 - PATCH - TCAP+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_include_LoCo!==1 (
    echo Installing :: Patching: Lost Colony + Lucike + XRM
    xcopy "!dr!360 - PATCH - LostColony+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    echo Installing :: Patching: TCAP + Lost Colony + Lucike + XRM
    xcopy "!dr!370 - PATCH - TCAP+LostColony+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Full Flat Galaxy Map
xcopy "!dr!399 - PATCH - Full Flat Galaxy Map\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_patch_w_x3_customizer!==1 (
    echo Installing :: X3 Customizer files 
    xcopy "!dr!400 - X3Customizer Files\BASE" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==0 (
    xcopy "!dr!400 - X3Customizer Files\Awesomefied" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    xcopy "!dr!400 - X3Customizer Files\Awesomefied_bullets" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==1 (
    xcopy "!dr!400 - X3Customizer Files\hull-low" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==2 (
    xcopy "!dr!400 - X3Customizer Files\hull-mid" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==3 (
    xcopy "!dr!400 - X3Customizer Files\hull-high" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP no, LC yes 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==0 if !_opt_include_LoCo!==1 (
    xcopy "!dr!400 - X3Customizer Files\LC" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP yes, LC no 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==0 (
    xcopy "!dr!400 - X3Customizer Files\TCAP" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP yes, LC yes 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    xcopy "!dr!400 - X3Customizer Files\TCAP-LC" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 (
    echo Installing :: CPP performance patch
    xcopy "!dr!420 - CPP weapon performance\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==0 (
    xcopy "!dr!420 - CPP weapon performance\Awesomefied_CPP" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    xcopy "!dr!420 - CPP weapon performance\Awesomefied_CPP_TBullets" "!X3AP_PATH!" /s /e /y /q
)

:: scripts
if !_opt_enable_scripts!==1 (

    echo Installing :: Libs
    xcopy "!dr!500 - Libs\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    REM these are base "script only" mods
    echo Installing :: Script only mods
    xcopy "!dr!520 - Scripts\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Script special
    xcopy "!dr!525 - Scripts Special\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Scripts - adding wares
    xcopy "!dr!600 - Scripts - wares [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Scripts - overwriting system files
    xcopy "!dr!610 - Scripts - overwrites [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Libs 2 [overwriting older versions / outdated exports in other mods]
    xcopy "!dr!800 - Libs 2 [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Dock Lookup Fix
    xcopy "!dr!900 - Dock Lookup Fix [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Missile Safety
    xcopy "!dr!950 - Missile Safety [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Fixes [for settings and scripts]
    xcopy "!dr!990 - Fixes [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

)

echo "*** LxXRM is installed! ***"
pause
goto menu


::-------------------------------------------------------------------------------------------------
:: Functions 
:: Checks the file is in the downloads (arg 1)
:CheckExtraDownloadExists
    IF Not EXIST "!dr!%~1" ( set _x3_missing=1 & echo %~1 !_c_red!*missing*!_c_reset! ) ELSE ( echo %~1 !_c_green!*ok*!_c_reset!)
EXIT /B 0

:: Params
::   1: The directory to install from (relative to LxXRM)
::   2: (Optional) Message of mod being installed
:install_single
    echo Installing :: %~2
    xcopy "!dr!%~1" "!X3AP_PATH!" /s /e /y /q
exit /B 0

[heimdallxx]

Hello, Resurrection mod doesn't have patch or other files right now just XRM 3.3 version available for download. And the installer doesn't accept it. Do you know any ways to fix it ?

Hi, I went ahead and edited the script to use the single Resurrection-XRM rar. All you should need to do is replace the `setup.bat` with the code below (in the spoiler), and rename the downloaded Resurrection rar (`X3 - Resurrection - v3.3 - XRM`) to `X3-ResurrectionXRM.rar`. (The name change is because the bat script didn't seem to like the name containing spaces and/or dashes . The other changes in the script were just me trying to understand a bat file)

The install seems to be going fine for me so far, but I haven't done any in-depth check to see if the newer resurrection has any issues with the rest of the pack.

Spoiler

Show

Code: Select all

@echo off
setlocal enabledelayedexpansion

:: Sanity execution direction setting
:: Needed when the bat file is executed as admin because its then executed in system32 
:: check: http://stackoverflow.com/questions/672693/windows-batch-file-starting-directory-when-run-as-admin/672721
FOR /F "delims=" %%I IN ("%0") DO SET dr=%%~dpI
cd /D %dr%

set _vars=!dr!/_settings.txt
set _x3ap_exe=X3AP.exe
set _x3_backup=_tmp_LXRM_BACKUP

set _f_x3ap=_DOWNLOADS\!_x3ap_exe!
set _f_x3_resurrection="_DOWNLOADS\X3-ResurrectionXRM.rar"
set _f_xrm_part_1=_DOWNLOADS\XRM1.30_PART_1.zip
set _f_xrm_part_2=_DOWNLOADS\XRM1.30d_PART_2.zip
set _f_xrm_part_3=_DOWNLOADS\XRM1.29_PART_3.zip

set pkg_130=130 - FP-08_09-XRM
set pkg_170=170 - FP-13_15-Resurrection

::-------------------------------------------------------------------
:: User options
set _opt_x3path=.
:: tc plots in ap
set _opt_enable_tcap=1
set _opt_disable_argon_terran_war=0
set _opt_include_LoCo=1
set _opt_xrm_hull_strength=2
set _opt_enable_CPP_performance=1
set _opt_patch_w_x3_customizer=1
set _opt_enable_awesomefied_weapons=1
set _opt_enable_awesomefied_bullets=1
set _opt_enable_scripts=1
set _opt_install_larger_font=1

::-------------------------------------------------------------------
set _c_white=[90m
set _c_red=[91m
set _c_green=[92m
set _c_reset=[0m

:: try to read in old settings
for /f "usebackq tokens=1* delims==" %%A in ("%_vars%") do set %%A=%%B


set _xtra=0

::-------------------------------------------------------------------------------------------------
:menu
set _x3_missing=0
set _x3_path_good=0
set _x3_TWareT_good=0
cls

echo LxXRM v3.0 Setup
echo.
echo Files
echo -----
:: First we must ensure the extra mods have been downloaded
call :CheckExtraDownloadExists !_f_x3ap!
call :CheckExtraDownloadExists !_f_x3_resurrection!
call :CheckExtraDownloadExists !_f_xrm_part_1!
call :CheckExtraDownloadExists !_f_xrm_part_2!
call :CheckExtraDownloadExists !_f_xrm_part_3!
echo.


:: Path to the x3 addon folder; this is where to install mods for x3ap.
set x3path_addon=!_opt_x3path!/addon

if !_xtra!==1 goto xtra


::-------------------------------------------------------------------------------------------------
:: Configuration Block

echo Configure
echo ---------

:: TCAP
if !_opt_enable_tcap!==0 (set t_opt_enable_tcap=!_c_white!no!_c_reset!) else (set t_opt_enable_tcap=!_c_green!yes!_c_reset!)
echo 1] Install and enable TCAP missions: !t_opt_enable_tcap!

:: XRM Argon/Terran War
if !_opt_disable_argon_terran_war!==0 (set t_opt_disable_argon_terran_war=!_c_white!no!_c_reset!) else (set t_opt_disable_argon_terran_war=!_c_green!yes!_c_reset!)
if !_opt_enable_tcap!==1 (set t_opt_disable_argon_terran_war=!_c_white!*disabled by TCAP*!_c_reset!)
echo 2] install XRM "No Argon/Terran War Pack" script?: !t_opt_disable_argon_terran_war!

:: Lost Colonies
if !_opt_include_LoCo!==0 (set t_opt_include_LoCo=!_c_white!no!_c_reset!) else (set t_opt_include_LoCo=!_c_green!yes!_c_reset!)
echo 3] Install Lost Colony systems? [recommended]: !t_opt_include_LoCo! 

:: XRM Hull Strength
if !_opt_xrm_hull_strength!==0 (set t_opt_xrm_hull_strength=!_c_white!no!_c_reset!)
if !_opt_xrm_hull_strength!==1 (set t_opt_xrm_hull_strength=!_c_green!low!_c_reset!)
if !_opt_xrm_hull_strength!==2 (set t_opt_xrm_hull_strength=!_c_green!medium!_c_reset! [recommended])
if !_opt_xrm_hull_strength!==3 (set t_opt_xrm_hull_strength=!_c_green!high!_c_reset!)
echo 4] XRM hull strength? None, Low, Medium (recommended) or High: !t_opt_xrm_hull_strength!

:: CPP Performance
if !_opt_enable_CPP_performance!==0 (set t_opt_enable_CPP_performance=!_c_white!no!_c_reset!) else (set t_opt_enable_CPP_performance=!_c_green!yes!_c_reset!)
echo 5] Use CPP performance weapon settings? (STRONGLY recommended for performance): !t_opt_enable_CPP_performance!

:: X3 Customizer
if !_opt_patch_w_x3_customizer!==0 (set t_opt_patch_w_x3_customizer=!_c_white!no!_c_reset!) else (set t_opt_patch_w_x3_customizer=!_c_green!yes!_c_reset!)
echo 6] Patch with the included X3 Customizer files? (STRONGLY recommended): !t_opt_patch_w_x3_customizer!

:: Awesomefied Weapons
if !_opt_enable_awesomefied_weapons!==0 (set t_opt_enable_awesomefied_weapons=!_c_white!no!_c_reset!) else (set t_opt_enable_awesomefied_weapons=!_c_green!yes!_c_reset!)
echo 7] Use Awesomefied weapon effects? (STRONGLY recommended for performance): !t_opt_enable_awesomefied_weapons!

:: Awesomefied Bullets
if !_opt_enable_awesomefied_bullets!==0 (set t_opt_enable_awesomefied_bullets=!_c_white!no!_c_reset!) else (set t_opt_enable_awesomefied_bullets=!_c_green!yes!_c_reset!)
if !_opt_enable_awesomefied_weapons!==0 (set t_opt_enable_awesomefied_bullets=!_c_white!*needs awesomefied weapon effects*!_c_reset!)
echo 8] Use Awesomefied bullets too? (additional performance boost): !t_opt_enable_awesomefied_bullets!

:: Use bundled Scripts
if !_opt_enable_scripts!==0 (set t_opt_enable_scripts=!_c_white!no!_c_reset!) else (set t_opt_enable_scripts=!_c_green!yes!_c_reset!)
echo 9] Add mods (scripts + libs) (DO NOT DISABLE): !t_opt_enable_scripts!

echo O] Options
echo.

::-------------------------------------------------------------------------------------------------

goto cmds
:xtra

echo Options
echo -------
if !_opt_install_larger_font!==0 (set t_opt_install_larger_font=!_c_white!no!_c_reset!) else (set t_opt_install_larger_font=!_c_green!yes!_c_reset!)
echo A] Install a larger font? (recommended for higher resolutions): !t_opt_install_larger_font!

echo O] Back to Configure
echo.

:cmds
set _x3_path_good=0
set _x3_TWareT_good=0
IF EXIST "!_opt_x3path!/!_x3ap_exe!" (
    set _x3_path_good=1
    set _x3_TWareT_good=1
    IF Not EXIST "!x3path_addon!/scripts/setup.cycrow.waremanager.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/scripts/setup.cycrow.pmanager.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/scripts/init.community.config.xml" (set _x3_path_good=0)
    IF Not EXIST "!x3path_addon!/types/TWareT.pck" (set _x3_TWareT_good=0)

    echo P] Path to Game: !_c_green!!_opt_x3path!!_c_reset!!_c_white!/!_x3ap_exe!!_c_reset! !_c_green!*FOUND*!_c_reset!
    if !_x3_path_good!==0 (
        set _x3_missing=1
        echo !_c_red!PluginManager files not found : Run it before install.!_c_reset!
    )
    if !_x3_path_good!==1 if !_x3_TWareT_good!==0 (
        set _x3_missing=1
        echo !_c_red!PluginManager *MUST* be CLOSED when playing or running SETUP.bat!_c_reset!
    )
) ELSE (
    set _x3_missing=1
    if "!_opt_x3path!"=="." (
        echo P] Path to Game: !_c_red!*SET PATH TO DIR*!_c_reset!
    ) ELSE (
        echo P] Path to Game: !_c_red!!_opt_x3path!!_c_reset! / can't find !_x3ap_exe! !_c_red!*INVALID*!_c_reset!
    )
)

if !_x3_missing!==0 (echo I] Install) else (echo I] !_c_white!Install!_c_reset! !_c_red!*NOT READY*!_c_reset!)
echo R] Refresh, D] Deinstall, Q] Quit
echo.

choice /c 123456789pridqo /M "Select: "

if !errorlevel!==1 (
    if !_opt_enable_tcap!==0 (set _opt_enable_tcap=1) else (set _opt_enable_tcap=0)
    goto menu
)

if !errorlevel!==2 (
    if !_opt_disable_argon_terran_war!==0 (set _opt_disable_argon_terran_war=1) else (set _opt_disable_argon_terran_war=0)
    goto menu
)
if !errorlevel!==3 (
    if !_opt_include_LoCo!==0 (set _opt_include_LoCo=1) else (set _opt_include_LoCo=0)
    goto menu
)

if !errorlevel!==4 (
    if !_opt_xrm_hull_strength!==3 (set _opt_xrm_hull_strength=0&goto menu)
    if !_opt_xrm_hull_strength!==2 (set _opt_xrm_hull_strength=3&goto menu)
    if !_opt_xrm_hull_strength!==0 (set _opt_xrm_hull_strength=1&goto menu)
    if !_opt_xrm_hull_strength!==1 (set _opt_xrm_hull_strength=2&goto menu)
    goto menu
)
if !errorlevel!==5 (
    if !_opt_enable_CPP_performance!==0 (set _opt_enable_CPP_performance=1) else (set _opt_enable_CPP_performance=0)
    goto menu
)
if !errorlevel!==6 (
    if !_opt_patch_w_x3_customizer!==0 (set _opt_patch_w_x3_customizer=1) else (set _opt_patch_w_x3_customizer=0)
    goto menu
)
if !errorlevel!==7 (
    if !_opt_enable_awesomefied_weapons!==0 (set _opt_enable_awesomefied_weapons=1) else (set _opt_enable_awesomefied_weapons=0)
    goto menu
)
if !errorlevel!==8 (
    if !_opt_enable_awesomefied_bullets!==0 (set _opt_enable_awesomefied_bullets=1) else (set _opt_enable_awesomefied_bullets=0)
    goto menu
)
if !errorlevel!==9 (
    if !_opt_enable_scripts!==0 (set _opt_enable_scripts=1) else (set _opt_enable_scripts=0)
    goto menu
)
if !errorlevel!==10 (
    echo.
    set /p _opt_x3path=[96mEnter X3AP Path: !_c_reset!
    echo '!_opt_x3path!'

    if "!_opt_x3path!"=="" (!_opt_x3path!=.)
    goto menu
)

if !errorlevel!==11 (
    goto menu
)

if !errorlevel!==12 (
    if !_x3_missing!==1 (echo.&echo Fix the missing parts first...&pause&goto menu)    
    goto install_start
)

if !errorlevel!==13 (
    goto un_files
)


if !errorlevel!==14 (
    >!_vars! echo _opt_x3path=!_opt_x3path!
    >>!_vars! echo _opt_enable_tcap=!_opt_enable_tcap!
    >>!_vars! echo _opt_disable_argon_terran_war=!_opt_disable_argon_terran_war!
    >>!_vars! echo _opt_include_LoCo=!_opt_include_LoCo!
    >>!_vars! echo _opt_xrm_hull_strength=!_opt_xrm_hull_strength!
    >>!_vars! echo _opt_enable_CPP_performance=!_opt_enable_CPP_performance!
    >>!_vars! echo _opt_patch_w_x3_customizer=!_opt_patch_w_x3_customizer!
    >>!_vars! echo _opt_enable_awesomefied_weapons=!_opt_enable_awesomefied_weapons!
    >>!_vars! echo _opt_enable_awesomefied_bullets=!_opt_enable_awesomefied_bullets!
    >>!_vars! echo _opt_enable_scripts=!_opt_enable_scripts!
    goto :EOF
)

if !errorlevel!==15 (
    if !_xtra!==0 (set _xtra=1) else (set _xtra=0)
    goto menu
)

if !errorlevel!==16 (
    if !_opt_install_larger_font!==0 (set _opt_install_larger_font=1) else (set _opt_install_larger_font=0)
    goto menu
)

goto menu

::-------------------------------------------------------------------------------------------------

:: DELETE files
:un_files

echo.
:: only when we have a valid path
if !_x3_path_good!==0 (
    echo "No X3AP path set ..."
    GOTO un_files_in
)
    
:: Already a backup directory? Then something is wrong
IF Not EXIST "!_opt_x3path!/!_x3_backup!" (
    echo "SKIP cleanup of !_opt_x3path! :: !_x3_backup! did not exists."
    GOTO un_files_in
)

set unfilesx=N
echo.

::-------------------------------------------------------------------------------------------------


:un_filesx_l
set /p "unfilesx=Deinstall mods and restore !_opt_x3path! files [y|n]: "
   if /i "!unfilesx:~,1!" EQU "Y" (goto un_filesx_do)
   if /i "!unfilesx:~,1!" EQU "N" (goto un_files_in)
goto un_filesx_l

::-------------------------------------------------------------------------------------------------


:un_filesx_do

:: remove all installed directories
rd /s /q "!_opt_x3path!\objects" 2>NUL
rd /s /q "!_opt_x3path!\dds" 2>NUL
rd /s /q "!_opt_x3path!\f" 2>NUL
rd /s /q "!_opt_x3path!\L" 2>NUL

Rem remove the addon / AP directories we had backuped
rd /s /q "!_opt_x3path!\addon\t" 2>NUL
rd /s /q "!_opt_x3path!\addon\scripts" 2>NUL
rd /s /q "!_opt_x3path!\addon\types" 2>NUL
rd /s /q "!_opt_x3path!\addon\mov" 2>NUL
rd /s /q "!_opt_x3path!\addon\loadscr" 2>NUL
rd /s /q "!_opt_x3path!\addon\PluginManager" 2>NUL
rd /s /q "!_opt_x3path!\addon\output" 2>NUL

rd /s /q "!_opt_x3path!\addon\Director" 2>NUL
rd /s /q "!_opt_x3path!\addon\Maps" 2>NUL
rd /s /q "!_opt_x3path!\addon\scripts.delete" 2>NUL
rd /s /q "!_opt_x3path!\addon\x3_customizer_logs" 2>NUL

del /Q "!_opt_x3path!\addon\05.*" 2>NUL
del /Q "!_opt_x3path!\addon\06.*" 2>NUL
del /Q "!_opt_x3path!\addon\07.*" 2>NUL
del /Q "!_opt_x3path!\addon\08.*" 2>NUL
del /Q "!_opt_x3path!\addon\09.*" 2>NUL
del /Q "!_opt_x3path!\addon\10.*" 2>NUL
del /Q "!_opt_x3path!\addon\11.*" 2>NUL
del /Q "!_opt_x3path!\addon\12.*" 2>NUL
del /Q "!_opt_x3path!\addon\13.*" 2>NUL
del /Q "!_opt_x3path!\addon\14.*" 2>NUL
del /Q "!_opt_x3path!\addon\15.*" 2>NUL
del /Q "!_opt_x3path!\addon\16.*" 2>NUL
del /Q "!_opt_x3path!\addon\17.*" 2>NUL
del /Q "!_opt_x3path!\addon\18.*" 2>NUL
del /Q "!_opt_x3path!\addon\19.*" 2>NUL
del /Q "!_opt_x3path!\addon\20.*" 2>NUL
del /Q "!_opt_x3path!\addon\21.*" 2>NUL
del /Q "!_opt_x3path!\addon\22.*" 2>NUL
del /Q "!_opt_x3path!\addon\23.*" 2>NUL
del /Q "!_opt_x3path!\addon\24.*" 2>NUL
del /Q "!_opt_x3path!\addon\25.*" 2>NUL

xcopy "!_opt_x3path!\!_x3_backup!\addon\t" "!_opt_x3path!\addon\t\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\scripts" "!_opt_x3path!\addon\scripts\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\types" "!_opt_x3path!\addon\types\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\mov" "!_opt_x3path!\addon\mov\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\loadscr" "!_opt_x3path!\addon\loadscr\" /s /e /y /q
xcopy "!_opt_x3path!\!_x3_backup!\addon\PluginManager" "!_opt_x3path!\addon\PluginManager\" /s /e /y /q

::-------------------------------------------------------------------------------------------------
:un_files_in
:: check we want clean up the LxXRM install too
set unfiles=N
:un_files_l
set /p "unfiles=Clean installed _DOWNLOAD packs too? [y|n]: "
   if /i "!unfiles:~,1!" EQU "Y" (goto un_files_do)
   if /i "!unfiles:~,1!" EQU "N" (goto un_files_no)
   echo Please type Y for Yes or N for No
   goto un_files_l

:un_files_do
set pkg=!pkg_130!
rd /s /q "!dr!!pkg!\_tmp" 2>NUL
rd /s /q "!dr!!pkg!\X3AP_COPYME" 2>NUL
set pkg=!pkg_170!
rd /s /q "!dr!!pkg!\_tmp" 2>NUL
rd /s /q "!dr!!pkg!\X3AP_COPYME" 2>NUL

::-------------------------------------------------------------------------------------------------
:un_files_no
goto menu

::-------------------------------------------------------------------------------------------------
:install_start
set start_y=N
echo.
:start_y_
set /p "start_y=Start to install? [y|n]: "
   if /i "!start_y:~,1!" EQU "Y" (goto unpack_xrm)
   if /i "!start_y:~,1!" EQU "N" (goto menu)
   echo Please type Y for Yes or N for No
   goto start_y_

::-------------------------------------------------------------------------------------------------
:: Unpack XRM
:unpack_xrm
set pkg=!pkg_130!
IF EXIST "!dr!!pkg!\X3AP_COPYME" (goto unpack_resurrection)

echo "*** Unpack: XRM... ***"
IF EXIST "!dr!!pkg!\_tmp" ( rd /s /q "!dr!!pkg!\_tmp" )
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_1!" -o"!dr!!pkg!\_tmp"
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_2!" -o"!dr!!pkg!\_tmp"
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_xrm_part_3!" -o"!dr!!pkg!\_tmp"

xcopy "!dr!!pkg!\_tmp\scripts_AP" "!dr!!pkg!\X3AP_COPYME\addon\scripts\" /s /e /y
xcopy "!dr!!pkg!\_tmp\t" "!dr!!pkg!\X3AP_COPYME\addon\t\" /s /e /y
xcopy "!dr!!pkg!\_tmp\director" "!dr!!pkg!\X3AP_COPYME\addon\director\" /s /e /y
xcopy "!dr!!pkg!\_tmp\loadscr" "!dr!!pkg!\X3AP_COPYME\addon\loadscr\" /s /e /y
xcopy "!dr!!pkg!\_tmp\mov" "!dr!!pkg!\X3AP_COPYME\addon\mov\" /s /e /y
xcopy "!dr!!pkg!\_tmp\soundtrack" "!dr!!pkg!\X3AP_COPYME\soundtrack\" /s /e /y

copy "!dr!!pkg!\_tmp\XRM1.30_PART_1.cat" "!dr!!pkg!\X3AP_COPYME\addon\08.cat"
copy "!dr!!pkg!\_tmp\XRM1.30_PART_1.dat" "!dr!!pkg!\X3AP_COPYME\addon\08.dat"

copy "!dr!!pkg!\_tmp\XRM1.30d_PART_2.cat" "!dr!!pkg!\X3AP_COPYME\addon\09.cat"
copy "!dr!!pkg!\_tmp\XRM1.30d_PART_2.dat" "!dr!!pkg!\X3AP_COPYME\addon\09.dat"

::-------------------------------------------------------------------------------------------------
:: Unpack Resurrection mod

:unpack_resurrection
set pkg=!pkg_170!
IF EXIST "!dr!!pkg!\X3AP_COPYME" (goto backup)

echo "*** Unpack: Resurrection... ***"
IF EXIST "!dr!!pkg!\_tmp" ( rd /s /q "!dr!!pkg!\_tmp" )
"!dr!_tools\7-Zip\7z.exe" x "!dr!!_f_x3_resurrection!" -o"!dr!!pkg!\_tmp"

md "!dr!!pkg!\X3AP_COPYME"
md "!dr!!pkg!\X3AP_COPYME/addon"

ren "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3 - Resurrection - v3.3 - XRM.cat" X3-RESURRECTION.cat
ren "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3 - Resurrection - v3.3 - XRM.dat" X3-RESURRECTION.dat

copy "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3-RESURRECTION.cat" "!dr!!pkg!\X3AP_COPYME\addon\13.cat"
copy "!dr!!pkg!\_tmp\X3 - Resurrection - v3.3 - XRM\X3-RESURRECTION.dat" "!dr!!pkg!\X3AP_COPYME\addon\13.dat"



::-------------------------------------------------------------------------------------------------
:: Create Backup Directory
:backup
IF EXIST "!_opt_x3path!/!_x3_backup!" ( goto install_mods)

echo "*** create  !_opt_x3path!\!_x3_backup! for backup files... ***"
xcopy "!_opt_x3path!\addon\t" "!_opt_x3path!\!_x3_backup!\addon\t\" /s /e /y /q
xcopy "!_opt_x3path!\addon\scripts" "!_opt_x3path!\!_x3_backup!\addon\scripts\" /s /e /y /q
xcopy "!_opt_x3path!\addon\types" "!_opt_x3path!\!_x3_backup!\addon\types\" /s /e /y /q
xcopy "!_opt_x3path!\addon\mov" "!_opt_x3path!\!_x3_backup!\addon\mov\" /s /e /y /q
xcopy "!_opt_x3path!\addon\loadscr" "!_opt_x3path!\!_x3_backup!\addon\loadscr\" /s /e /y /q
xcopy "!_opt_x3path!\addon\PluginManager" "!_opt_x3path!\!_x3_backup!\addon\PluginManager\" /s /e /y /q
copy "!_opt_x3path!\!_x3ap_exe!" "!_opt_x3path!\!_x3_backup!\!_x3ap_exe!"


::-------------------------------------------------------------------------------------------------
:: Install Mods
:install_mods

echo Prepare Base files....
copy "!dr!\!_f_x3ap!" "!_opt_x3path!\!_x3ap_exe!"
:: XRM comes with a 00044.xml in the fake mod
:: to enable it, the 00044.xxx in the /mov must be removed 
del /Q "!x3path_addon!\mov\00044.xml" 2>NUL
del /Q "!x3path_addon!\mov\00044.pck" 2>NUL
:: We install the latest, fixed MK3 Trader scripts
:: remove all previous files to avoid problems
del /Q "!x3path_addon!\scripts\plugin.autotrade*.pck" 2>NUL
del /Q "!x3path_addon!\scripts\plugin.autotrade*.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.signal.killed.trader.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.signal.attacked.trader.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.ship.sh.attack.trader.flee.xml" 2>NUL
del /Q "!x3path_addon!\scripts\!ship.cmd.jump.std.xml" 2>NUL
del /Q "!x3path_addon!\scripts\lib.get.jumpable.gates.xml" 2>NUL
del /Q "!x3path_addon!\t\1500-L*.xml" 2>NUL

set X3AP_PATH=!_opt_x3path!

echo Installing :: BASE [hud, etc]
xcopy "!dr!000 - BASE\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
if !_opt_install_larger_font!==1 (
    echo Installing :: larger Font
    xcopy "!dr!000 - BASE\LargerFont" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: MK3 reloaded
xcopy "!dr!010 - MK3-Reloaded\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Mars [scripts and t only]
xcopy "!dr!050 - Mars\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Complex Cleaner AP
xcopy "!dr!100 - FP-05-Complex Cleaner\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Lucike [full + modification mod]
xcopy "!dr!110 - FP-06-Lucike\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!110 - FP-06-Lucike\X3TC_AP_Prospector_3_3_07_Signal_Targeted_V1.5" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!110 - FP-06-Lucike\X3TC_AP_Com_Agent_3_4_09_Signal_Targeted_V1.2" "!X3AP_PATH!" /s /e /y /q

echo Installing :: eEQ Docks AP
xcopy "!dr!120 - FP-07-eEQDocks_AP\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: XRM 1.30d
xcopy "!dr!130 - FP-08_09-XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!130 - FP-08_09-XRM\X3AP_mars" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_tcap!==0 if !_opt_disable_argon_terran_war!==1 (
    echo Installing :: XRM "no war scripts"
    xcopy "!dr!130 - FP-08_09-XRM\X3AP_NoWar" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Saturn Complex Hub XRM [AP]
xcopy "!dr!140 - FP-10-SaturnComplexHub\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Advanced Complex Hub [AP]
xcopy "!dr!150 - FP-11-AdvancedComplexHub\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: No Ring Gates
xcopy "!dr!160 - FP-12-NoRingGates\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Resurrection
xcopy "!dr!170 - FP-13_15-Resurrection\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: FM 14 - TWareT
xcopy "!dr!180 - FP-16 - TWareT\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_tcap!==1 (
    echo Installing :: TCAP
    xcopy "!dr!200 - FP-17-TCAP [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_include_LoCo!==1 (
    echo Installing :: Lost Colony XRM
    xcopy "!dr!210 - Lost Colony XRM [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    echo Installing :: TCAP for Lost Colony files
    xcopy "!dr!215 - TCAP_Lost Colony [optional]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Patching: Lucike + XRM [ types / t ]
xcopy "!dr!250 - Lucike+XRM merged\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Revelation XRM
xcopy "!dr!260 - Revelation XRM-AP\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
xcopy "!dr!260 - Revelation XRM-AP\Fixes" "!X3AP_PATH!" /s /e /y /q

echo Installing :: ADS + Pirate Guild + Yaki Guild merged
xcopy "!dr!270 - ADS + PirateGuild + Yaki\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Phanon XRM
xcopy "!dr!280 - Phanon XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

echo Installing :: Improved Khaak
xcopy "!dr!290 - Improved Khaak\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_enable_awesomefied_weapons!==1 (
    echo Installing :: Awesomefied Weapons
    xcopy "!dr!300 - Awesomefied Weapons\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    echo Installing :: Awesomefied Weapons (+Bullets)
    xcopy "!dr!300 - Awesomefied Weapons\bullets" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Bounce
xcopy "!dr!310 - Bounce\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_xrm_hull_strength!==1 (
    echo Installing ::XRM Hull: low [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\low" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_xrm_hull_strength!==2 (
    echo Installing :: XRM Hull: medium [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\medium" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_xrm_hull_strength!==3 (
    echo Installing :: XRM Hull: high [TShips.txt]
    xcopy "!dr!320 - LxRM Hull\high" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 (
    echo Installing :: Patching: TCAP + Lucike + XRM
    xcopy "!dr!350 - PATCH - TCAP+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_include_LoCo!==1 (
    echo Installing :: Patching: Lost Colony + Lucike + XRM
    xcopy "!dr!360 - PATCH - LostColony+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    echo Installing :: Patching: TCAP + Lost Colony + Lucike + XRM
    xcopy "!dr!370 - PATCH - TCAP+LostColony+Lucike+XRM\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

echo Installing :: Full Flat Galaxy Map
xcopy "!dr!399 - PATCH - Full Flat Galaxy Map\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

if !_opt_patch_w_x3_customizer!==1 (
    echo Installing :: X3 Customizer files 
    xcopy "!dr!400 - X3Customizer Files\BASE" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==0 (
    xcopy "!dr!400 - X3Customizer Files\Awesomefied" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    xcopy "!dr!400 - X3Customizer Files\Awesomefied_bullets" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==1 (
    xcopy "!dr!400 - X3Customizer Files\hull-low" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==2 (
    xcopy "!dr!400 - X3Customizer Files\hull-mid" "!X3AP_PATH!" /s /e /y /q
)
if !_opt_patch_w_x3_customizer!==1 if !_opt_xrm_hull_strength!==3 (
    xcopy "!dr!400 - X3Customizer Files\hull-high" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP no, LC yes 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==0 if !_opt_include_LoCo!==1 (
    xcopy "!dr!400 - X3Customizer Files\LC" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP yes, LC no 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==0 (
    xcopy "!dr!400 - X3Customizer Files\TCAP" "!X3AP_PATH!" /s /e /y /q
)

:: CFiles + TCAP yes, LC yes 
if !_opt_patch_w_x3_customizer!==1 if !_opt_enable_tcap!==1 if !_opt_include_LoCo!==1 (
    xcopy "!dr!400 - X3Customizer Files\TCAP-LC" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 (
    echo Installing :: CPP performance patch
    xcopy "!dr!420 - CPP weapon performance\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==0 (
    xcopy "!dr!420 - CPP weapon performance\Awesomefied_CPP" "!X3AP_PATH!" /s /e /y /q
)

if !_opt_enable_CPP_performance!==1 if !_opt_enable_awesomefied_weapons!==1 if !_opt_enable_awesomefied_bullets!==1 (
    xcopy "!dr!420 - CPP weapon performance\Awesomefied_CPP_TBullets" "!X3AP_PATH!" /s /e /y /q
)

:: scripts
if !_opt_enable_scripts!==1 (

    echo Installing :: Libs
    xcopy "!dr!500 - Libs\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    REM these are base "script only" mods
    echo Installing :: Script only mods
    xcopy "!dr!520 - Scripts\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Script special
    xcopy "!dr!525 - Scripts Special\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Scripts - adding wares
    xcopy "!dr!600 - Scripts - wares [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Scripts - overwriting system files
    xcopy "!dr!610 - Scripts - overwrites [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Libs 2 [overwriting older versions / outdated exports in other mods]
    xcopy "!dr!800 - Libs 2 [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Dock Lookup Fix
    xcopy "!dr!900 - Dock Lookup Fix [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Missile Safety
    xcopy "!dr!950 - Missile Safety [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

    echo Installing :: Fixes [for settings and scripts]
    xcopy "!dr!990 - Fixes [nobatch]\X3AP_COPYME" "!X3AP_PATH!" /s /e /y /q

)

echo "*** LxXRM is installed! ***"
pause
goto menu


::-------------------------------------------------------------------------------------------------
:: Functions 
:: Checks the file is in the downloads (arg 1)
:CheckExtraDownloadExists
    IF Not EXIST "!dr!%~1" ( set _x3_missing=1 & echo %~1 !_c_red!*missing*!_c_reset! ) ELSE ( echo %~1 !_c_green!*ok*!_c_reset!)
EXIT /B 0

:: Params
::   1: The directory to install from (relative to LxXRM)
::   2: (Optional) Message of mod being installed
:install_single
    echo Installing :: %~2
    xcopy "!dr!%~1" "!X3AP_PATH!" /s /e /y /q
exit /B 0

Hi, your solution is way better and easier. thank you.

[Davith]

Are the TC plots working for anyone else?
I've tried the Terran Defender, Argon Patriot and Bankrupt Assassin starts, and for each of them only the AP plots are available.
The TCinAP mod is definitely installed, and I get the message at the start saying it has loaded.